" Set nocompatible mode
set nocompatible

" Windows-like keybindings and settings
source $VIMRUNTIME/mswin.vim
startinsert
set mouse=a
"set insertmode
"set hidden

" Make cursor keys ignore wrapping
inoremap <silent> <Down> <C-R>=pumvisible() ? "\<lt>Down>" : "\<lt>C-O>gj"<CR>
inoremap <silent> <Up>   <C-R>=pumvisible() ? "\<lt>Up>" : "\<lt>C-O>gk"<CR>

" Basic UI settings
colorscheme desert
set history=100
set confirm
set ruler
set showcmd
set number
set nowrap
set wildmenu
set wildmode=longest,full
"set showmatch

" Searching
set ignorecase
set smartcase
set incsearch
set hlsearch

" Indentation
set autoindent
set smartindent
set expandtab
set smarttab
set tabstop=4
set softtabstop=4
set shiftwidth=4

" Filetype detection and syntax highlighting
filetype plugin indent on
syntax on

" Highlight current line
highlight cursorline cterm=none ctermbg=black gui=none guibg=grey30
autocmd InsertLeave * setlocal nocursorline
autocmd InsertEnter * setlocal cursorline

" Set file encoding automagically (use enca)
function! GetEncoding(f)
    let e = system('enca -Pe "' . a:f . '"')
    let e = substitute(e, '/.*', '', '')
    if e =~ 'unknown'
        return 'utf-8'
    endif
    return e
endfunc
autocmd BufReadPre * exec "set fileencodings=" . GetEncoding(expand('<afile>'))

" Tab completion
function! CleverTab(command)
    if strpart(getline('.'), 0, col('.')-1) =~ '^\s*$'
        if a:command == 'next'
            return "\<Tab>"
        elseif a:command == 'prev'
            return "\<BS>"
        endif
    else
        if a:command == 'next'
            return "\<C-N>"
        elseif a:command == 'prev'
            return "\<C-P>"
        endif
    endif
endfunction

inoremap <C-Space> <C-X><C-O>
inoremap <Tab>     <C-R>=CleverTab('next')<CR>
inoremap <S-Tab>   <C-R>=CleverTab('prev')<CR>

" (Un)comment selection
function! ToggleComment(CommentLeader, CommentTrailer)
    let hls = @/
    if getline(".") =~ a:CommentLeader
        execute ":s/^\\(\\s*\\)" . a:CommentLeader . "/\\1/"
        execute ":s/" . a:CommentTrailer . "$//"
    else
        execute ":s/^\\(\\s*\\)/\\1" . a:CommentLeader . "/"
        execute ":s/$/" . a:CommentTrailer . "/"
    endif
    let @/ = hls
endfunction

vnoremap <C-D>     :call ToggleComment('### ', '')<CR>
autocmd FileType c      vnoremap <C-D> :call ToggleComment('\/\/ ', '')<CR>
autocmd FileType php    vnoremap <C-D> :call ToggleComment('\/\/ ', '')<CR>
autocmd FileType python vnoremap <C-D> :call ToggleComment('# ', '')<CR>
autocmd FileType sh     vnoremap <C-D> :call ToggleComment('# ', '')<CR>
autocmd FileType html   vnoremap <C-D> :call ToggleComment('<!-- ', ' -->')<CR>

" (Un)indent selection
function! Indenter(IndentChar)
    normal gv
    execute "normal " . a:IndentChar
    normal gv
endfunction

vnoremap <Tab>     :<C-u>call Indenter(">")<CR>
vnoremap <S-Tab>   :<C-u>call Indenter("<")<CR>

" Intelligent End key (from Cream)
function! Cream_motion_home()
" Original Concept: http://www.derwok.de/downloads/index.html
    " get current column
    let oldcol = col('.')
    " go to first non-white
    normal g^
    " get current column, new
    let newcol = col('.')
    " if already were at first-non-white, toggle
    if (oldcol == newcol)
        " if we're on the first line, stop, otherwise toggle
        if (&wrap == 1) && (newcol > Cream_linewidth())
            " stop
        else
            execute "normal gI\<C-o>"
            let lastcol = col('.')
            " already were at first col?
            if (newcol == lastcol)
                " fix being stuck on second column if a one character line
                if (newcol == oldcol)
                    " terminate, ensure at beginning
                    normal i
                else
                    " toggle back to first non-white
                    normal g^
                endif
            else
                " toggle to first col
                execute "normal gI\<C-o>"
            endif
        endif
    endif
endfunction

inoremap <Home>    <C-o>:call Cream_motion_home()<CR>
vnoremap <Home>    :call Cream_motion_home()<CR>

" ESC toggle normal/insert mode... broken :-(
"nnoremap <silent> <ESC> :startinsert<CR> 

" Keybindings (like Windows, Nano, Konqueror, etc.)
inoremap <C-K>     <C-O>dd
nnoremap <C-K>     dd
inoremap <C-U>     <C-O>P
nnoremap <C-U>     P
inoremap <C-F>     <C-O>/
nnoremap <C-F>     /
inoremap <F3>      <C-O>n
nnoremap <F3>      n
inoremap <S-F3>    <C-O>N
nnoremap <S-F3>    N
inoremap <C-T>     <C-O>:tabnew<CR>
nnoremap <C-T>     :tabnew<CR>
inoremap <C-Left>  <C-O>:tabprevious<CR>
nnoremap <C-Left>  :tabprevious<CR>
inoremap <C-Right> <C-O>:tabnext<CR>
nnoremap <C-Right> :tabnext<CR>
inoremap <C-Up>    <C-O><C-W>w
nnoremap <C-Up>    <C-W>w
inoremap <C-Down>  <C-O><C-W>W
nnoremap <C-Down>  <C-W>W